class TInformationSystemTotalReactor extends Info
    placeable;

#exec OBJ LOAD FILE=UT2003Fonts.utx
    
var() ScriptedTexture DataScreen;

simulated function PostBeginPlay()
{
    if (DataScreen != None)
    {
        DataScreen.Client = self;
        SetTimer(0.125, true);
        Enable('Timer');
    }
}

simulated function Timer()
{
    DataScreen.Revision++;
}

simulated event RenderTexture(ScriptedTexture Tex)
{
    local TReactorObjective R;
    local string ReactorHealthCount;
    local string ReactorHealthMax;
    local Mover D;
    local string DoorStatus;
    local Color DoorStatusColor;
    
    
    local Material BGMaterial;
    local Color ColorTile;
    
    
    
    local int TableWidthDescription;
    local int TableWidthData;
    local int TableHeightCell;
    local int TableX;
    local int TableY;
    
    local int TableOffsetX;
    local int TableOffsetY;
    
    local Color TableBaseColor;
    local Color TableTopCaptionColor;
    local Color TableDescriptionColor;
    local Color TableCellColor;
    local Color TableTextColor;
    
    local Color MessageBaseColor;
    local Color MessageTextColor;
    
    //////////////////
    
    BGMaterial = Texture'TTexturePack.Wallpaper3';
    
    ColorTile.B = 255;
    ColorTile.G = 255;
    ColorTile.R = 255;
    ColorTile.A = 255;
    
    

    
    
    ForEach AllActors(class'TReactorObjective', R)
    {
  
  if (R.Health >= 0)
  {
   ReactorHealthCount = string(R.Health);
  }
  else
  {
   ReactorHealthCount = "0";
  }
  
  ReactorHealthMax = string(R.DamageCapacity);

    }    
    
    

    ForEach AllActors(class'Mover', D)
    {
  if (D.Tag == 'MoverDoor1')
  {
   
   //Close
   if ( (D.KeyNum == 0) && (D.PrevKeyNum == 0) )
   {
    DoorStatusColor.B = 0;
    DoorStatusColor.G = 0;
    DoorStatusColor.R = 240;
    DoorStatusColor.A = 240;
    DoorStatus = "Close";
   }
   
   
   //Opening...
   if ( (D.KeyNum == 1) && (D.PrevKeyNum == 0) )
   {
    DoorStatusColor.B = 0;
    DoorStatusColor.G = 240;
    DoorStatusColor.R = 120;
    DoorStatusColor.A = 240;
    DoorStatus = "Opening...";
   }
   
   
   //Closing...
   if ( (D.KeyNum == 0) && (D.PrevKeyNum == 1) )
   {
    DoorStatusColor.B = 0;
    DoorStatusColor.G = 120;
    DoorStatusColor.R = 240;
    DoorStatusColor.A = 240;
    DoorStatus = "Closing...";
   }
   
   
   //Open
   if ( (D.KeyNum == 1) && (D.PrevKeyNum == 1) )
   {
    DoorStatusColor.B = 0;
    DoorStatusColor.G = 240;
    DoorStatusColor.R = 0;
    DoorStatusColor.A = 240;
    DoorStatus = "Open";
   }
  }
    }

    
    
    
    
    
    
    
    TableWidthDescription = 200;
    TableWidthData = 160;
    TableHeightCell = 24;
    TableX = (Tex.USize - (TableWidthDescription + TableWidthData)) / 2;
    TableY = (Tex.VSize - (TableHeightCell + 3 * TableHeightCell)) / 2;
    
    
    TableOffsetX = 0;
    TableOffsetY = 0;
    
    
    TableBaseColor.B = 48;
    TableBaseColor.G = 48;
    TableBaseColor.R = 48;
    TableBaseColor.A = 192;

    TableTopCaptionColor.B = 0;
    TableTopCaptionColor.G = 0;
    TableTopCaptionColor.R = 255;
    TableTopCaptionColor.A = 224;
    
    TableDescriptionColor.B = 96;
    TableDescriptionColor.G = 96;
    TableDescriptionColor.R = 224;
    TableDescriptionColor.A = 192;

    TableCellColor.B = 32;
    TableCellColor.G = 32;
    TableCellColor.R = 32;
    TableCellColor.A = 192;
    
    TableTextColor.B = 255;
    TableTextColor.G = 255;
    TableTextColor.R = 255;
    TableTextColor.A = 224;

    MessageBaseColor.B = 16;
    MessageBaseColor.G = 16;
    MessageBaseColor.R = 16;
    MessageBaseColor.A = 248;

    MessageTextColor.B = 0;
    MessageTextColor.G = 0;
    MessageTextColor.R = 255;
    MessageTextColor.A = 224;
    
    ///////////////
    
    
    

    //Background
    Tex.DrawTile(0, 0, Tex.USize, Tex.VSize, 0, 0, BGMaterial.MaterialUSize(), BGMaterial.MaterialVSize(), BGMaterial, ColorTile);    
    
    

    
    //Table Caption
    DrawBoxFrame(Tex, TableX, TableY, TableWidthDescription + TableWidthData, TableHeightCell, TableBaseColor, TableTopCaptionColor, "Reactor Info", TableTextColor);
    

    
    TableOffsetX = 0;
    TableOffsetY = TableOffsetY + TableHeightCell;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthDescription, TableHeightCell, TableBaseColor, TableDescriptionColor, "Health Count", TableTextColor);
    TableOffsetX = TableOffsetX + TableWidthDescription;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthData, TableHeightCell, TableBaseColor, TableCellColor, ReactorHealthCount, TableTextColor);
    TableOffsetX = TableOffsetX + TableWidthData;
    
    
    
    TableOffsetX = 0;
    TableOffsetY = TableOffsetY + TableHeightCell;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthDescription, TableHeightCell, TableBaseColor, TableDescriptionColor, "Health Max", TableTextColor);
    TableOffsetX = TableOffsetX + TableWidthDescription;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthData, TableHeightCell, TableBaseColor, TableCellColor, ReactorHealthMax, TableTextColor);
    TableOffsetX = TableOffsetX + TableWidthData;
    
    
    
    TableOffsetX = 0;
    TableOffsetY = TableOffsetY + TableHeightCell;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthDescription, TableHeightCell, TableBaseColor, TableDescriptionColor, "Door Reactor", TableTextColor);
    TableOffsetX = TableOffsetX + TableWidthDescription;
    
    DrawBoxFrame(Tex, TableX + TableOffsetX, TableY + TableOffsetY, TableWidthData, TableHeightCell, TableBaseColor, TableCellColor, DoorStatus, DoorStatusColor);
    TableOffsetX = TableOffsetX + TableWidthData;    
    
    
    
    if (ReactorHealthCount == "0")
    {
  DrawBox(Tex, (Tex.USize - (TableWidthDescription + TableWidthData + 128)) / 2, TableY - 96, TableWidthDescription + TableWidthData + 128, 48, 0, MessageBaseColor);
  Tex.DrawText((Tex.USize - (TableWidthDescription + TableWidthData + 128)) / 2 + 4, TableY - 96 + 4, "Reactor Terminated", Font'UT2003Fonts.FontEurostile24', MessageTextColor);
    }
    
}

simulated function DrawBoxFrame(ScriptedTexture Tex, float PosX, float PosY, float XL, float YL, Color ColorBase, Color ColorTile, string InfoText, Color InfoTextColor)
{
    DrawBox(Tex, PosX, PosY, XL, YL, 0, ColorBase);
    DrawBox(Tex, PosX + 1, PosY + 1, XL - 1 - 1, YL - 1 - 1, 0, ColorTile);
    Tex.DrawText(PosX + 4, PosY + 2, InfoText, Font'UT2003Fonts.FontEurostile12', InfoTextColor);
}

simulated function DrawBox(ScriptedTexture Tex, float PosX, float PosY, float XL, float YL, float ScaleK, Color ColorTile)
{
    local float UL, VL;
    local float BorderUL, BorderVL;
    local float BorderXL, BorderYL;
    local Material BGMaterial;
    
    BGMaterial = Texture'TTexturePack.TableTexture';
    
    UL = BGMaterial.MaterialUSize();
    VL = BGMaterial.MaterialVSize();
    BorderUL = int((UL - 0.5) / 2);
    BorderVL = int((VL - 0.5) / 2);
    BorderXL = BorderUL * ScaleK;
    BorderYL = BorderVL * ScaleK;

    //Left
    Tex.DrawTile(PosX, PosY, BorderXL, BorderYL, 0, 0, BorderUL, BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX, PosY + BorderYL, BorderXL, YL - 2 * BorderYL, 0, BorderVL, BorderUL, VL - 2 * BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX, PosY + YL - BorderYL, BorderXL, BorderYL, 0, VL - BorderVL, BorderUL, BorderVL, BGMaterial, ColorTile);

    //Middle
    Tex.DrawTile(PosX + BorderXL, PosY, XL - 2 * BorderXL, BorderYL, BorderUL, 0, UL - 2 * BorderUL, BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX + BorderXL, PosY + BorderYL, XL - 2 * BorderXL, YL - 2 * BorderYL, BorderUL, BorderVL, UL - 2 * BorderUL, VL - 2 * BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX + BorderXL, PosY + YL - BorderYL, XL - 2 * BorderXL, BorderYL, BorderUL, VL - BorderVL, UL - 2 * BorderUL, BorderVL, BGMaterial, ColorTile);

    //Right
    Tex.DrawTile(PosX + XL - BorderXL, PosY, BorderXL, BorderYL, UL - BorderUL, 0, BorderUL, BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX + XL - BorderXL, PosY + BorderYL, BorderXL, YL - 2 * BorderYL, UL - BorderUL, BorderVL, BorderUL, VL - 2 * BorderVL, BGMaterial, ColorTile);
    Tex.DrawTile(PosX + XL - BorderXL, PosY + YL - BorderYL, BorderXL, BorderYL, UL - BorderUL, VL - BorderVL, BorderUL, BorderVL, BGMaterial, ColorTile);
}

defaultproperties
{
     bNoDelete=True
     bAlwaysRelevant=True
     RemoteRole=ROLE_SimulatedProxy
     Texture=Texture'TTexturePack.InformationSystem'
     DrawScale=0.125000
     bSelected=True
}