class BC_MotionBlurActor extends Actor;

var PlayerController    PC;
var MotionBlur         MBlur;
var float            BlurEndTime;
var float            BlurTime;
var float            BlurFactor;
var bool            bNoFade;
var bool            bIsBlurred;
var bool            bWasDead;

simulated function PreBeginPlay()
{
   if (!class'BallisticMod'.default.bUseMotionBlur)
      Destroy();
}

simulated function InitMotionBlur (float NewBlurFactor, float NewBlurTime, optional bool bNoFading, optional bool bNoAdd)
{
   PC = level.GetLocalPlayerController();
   if (PC == None || !class'BallisticMod'.default.bUseMotionBlur)
      Destroy();
   else if (bNoAdd || BlurEndTime < level.TimeSeconds)
   {
      BlurFactor = NewBlurFactor;
      BlurTime = NewBlurTime;
      BlurEndTime = level.TimeSeconds + NewBlurTime;
      bNoFade = bNoFading;
      StartBlur();
   }
   else if ((BlurEndTime-level.TimeSeconds) + NewBlurTime > 10)
   {
      BlurFactor += NewBlurFactor;
      BlurTime += NewBlurTime;
      BlurEndTime = level.TimeSeconds + 10;
      bNoFade = bNoFading;
      StartBlur();
   }
   else
   {
      BlurFactor += NewBlurFactor;
      BlurTime += NewBlurTime;
      BlurEndTime += NewBlurTime;
      bNoFade = bNoFading;
      StartBlur();
   }
}

simulated function StartBlur()
{
   local int i;

   if (PC == None)
      return;

   // To avoid conflict problems, we'll hijack any existing 'MotionBlur' rather than spawning a new one...
   for (i=0;i<PC.CameraEffects.length;i++)
      if (MotionBlur(PC.CameraEffects[i]) != None)   {
         MBlur = MotionBlur(PC.CameraEffects[i]);
         break;                    }

   if (MBlur == None)
      MBlur = new class'MotionBlur';

   if (bNoFade)
      MBlur.BlurAlpha = 255 - 255 * FMin(1, BlurFactor);
   else
      MBlur.BlurAlpha = 255 - 255 * FMin(1, BlurFactor * ((BlurEndTime - level.TimeSeconds) / BlurTime));

   bIsBlurred=true;
   if (PC.CameraEffects.length < 1 || PC.CameraEffects[PC.CameraEffects.length-1] != MBlur)
      PC.AddCameraEffect(MBlur,true);
}

simulated event Tick(float DT)
{
   if (PC == None)
   {
      Destroy();
      return;
   }
   if (!bIsBlurred)
      return;
   if (!PC.IsDead())
   {
      if (bWasDead)
      {
         bIsBlurred=false;
         UnBlurIt();
         BlurTime = 0;
         bWasDead = false;
         return;
      }
   }
   else
      bWasDead = true;
   if (level.TimeSeconds > BlurEndTime)
   {
      bIsBlurred=false;
      UnBlurIt();
      BlurTime = 0;
   }
   else if (MBlur != None)
   {
      if (bNoFade)
         MBlur.BlurAlpha = 255 - 255 * FMin(1, BlurFactor);
      else
         MBlur.BlurAlpha = 255 - 255 * FMin(1, BlurFactor * ((BlurEndTime - level.TimeSeconds) / BlurTime));
   }
}

simulated event Destroyed()
{
   UnBlurIt();
   super.Destroyed();
}
simulated function UnBlurIt ()
{
//   PC.ConsoleCommand("set ini:Engine.Engine.AudioDevice SoundVolume"@OldVolume);
   if (MBlur != None)
      PC.RemoveCameraEffect(MBlur);
}

static function BC_MotionBlurActor DoMotionBlur (PlayerController PC, float NewBlurFactor, float NewBlurTime, optional bool bNoFading)
{
   local BC_MotionBlurActor B;
   local int i;

   if (PC == None ||!class'BallisticMod'.default.bUseMotionBlur)
      return none;

   for (i=0;i<PC.Attached.length;i++)
      if (BC_MotionBlurActor(PC.Attached[i]) != None)
      {
         B = BC_MotionBlurActor(PC.Attached[i]);
         break;
      }
   if (B == None)
   {
      B = PC.Spawn(default.class, PC,,PC.Location);
      B.SetBase(PC);
   }
   if (B != None)
      B.InitMotionBlur (NewBlurFactor, NewBlurTime, bNoFading);
   return B;
}

defaultproperties
{
     bHidden=True
     RemoteRole=ROLE_None
}