class Kickable_ExplodingBarrel extends KActor placeable;

var(KEB) int               Health;
var(KEB) class<actor>      DestroyedEffect;
var(KEB) class<DamageType> DestroyedDamageType;
var(KEB) sound             DestroyedSound;
var(KEB) float             DestroyedDamageRadius;
var(KEB) float             DestroyedDamage;
var(KEB) float             DestroyedMomentum;
var(KEB) float             ImpactDamage;
var(KEB) float             MinImpact;

var Pawn Killer;
var bool Exploaded;

function bool SelfTriggered()
{
       return true;
}

function Bump( Actor Other )
{
       local vector BumpImpulse;

         if (Health > 0)
          {
           BumpImpulse = Other.Velocity*Other.Mass;
           if ( BumpImpulse.Z > 0 )
            BumpImpulse.Z = VSize(BumpImpulse);
           KAddImpulse(BumpImpulse, Location);
           if (Killer == none)
            Killer = Pawn(Other);
          }
         else if (Exploaded == false)
          Explode(Pawn(Other));

         if ((Exploaded == false) && (Killer != none) && (Other != Killer) )
          Explode(Pawn(Other));
}

function TakeDamage( int Damage, Pawn InstigatedBy, Vector HitLocation, Vector Momentum, class<DamageType> DamageType)
{
       Health -= Damage;

       if (( Health <= 0 ) && (Exploaded == false))
        Explode(InstigatedBy);

       Super.TakeDamage( Damage, InstigatedBy, HitLocation, Momentum, DamageType);
}

event KImpact(actor        other, vector pos, vector impactVel, vector impactNorm)
{
       Super.KImpact(other, pos, impactVel, impactNorm);
       Killer = none;
       if (VSize(impactVel) > MinImpact)
         Health -= VSize(impactVel)*ImpactDamage;
}

function Explode( Pawn InstigatedBy )
{
       local Actor Other;

       Exploaded = true;

       if ( DestroyedEffect != None )
        Spawn( DestroyedEffect, Owner,, Location );

       foreach RadiusActors(class'Actor', Other, DestroyedDamageRadius)
        Other.TakeDamage(DestroyedDamage, InstigatedBy, Other.Location, Normal(Other.Location - Location)*DestroyedMomentum, DestroyedDamageType);

       bHidden = true;
       SetCollision(false, false, false);
       SetPhysics(Phys_None);
}

defaultproperties
{
           StaticMesh=StaticMesh'AS_Decos.ExplodingBarrel'
           ImpactDamage=1
           MinImpact=10
           Health=100
}